BC846B.lib
**********************************************************
*
* BC846B
*
* Nexperia
*
* General purpose NPN transistor
* IC   = 100 mA
* VCEO = 65 V 
* hFE  = 110 - 450 @ 5V/2mA
* 
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 23
* 
* Package Pin 1: Base
* Package Pin 2: Emitter
* Package Pin 3: Collector
* 
*
* Extraction date (week/year): 39/2018
* Spicemodel includes temperature dependency
*
**********************************************************
*#
*
* Diode D1, Transistor Q2 and resistor RQ 
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
*
.SUBCKT BC846B 1 2 3
Q1 1 2 3 Transistor AREA 0.9755
Q2 11 2 3 Transistor AREA 0.0245
RQ 11 1 1693
D1 2 1 Diode
*
.MODEL Transistor NPN
+ IS = 1.089E-014
+ NF = 0.9981
+ ISE = 3.006E-015
+ NE = 1.369
+ BF = 288
+ IKF = 0.08473
+ VAF = 35.12
+ NR = 1
+ ISC = 1.068E-014
+ NC = 1.357
+ BR = 8.655
+ IKR = 0.009746
+ VAR = 25
+ RB = 300
+ IRB = 3.58E-005
+ RBM = 0.8
+ RE = 1.882
+ RC = 0.387
+ XTB = 1.734
+ EG = 1.11
+ XTI = 5.656
+ CJE = 1.284E-011
+ VJE = 0.6863
+ MJE = 0.3393
+ TF = 7.33E-010
+ XTF = 8.656
+ VTF = 2
+ ITF = 0.8548
+ PTF = 0
+ CJC = 3.458E-012
+ VJC = 0.5671
+ MJC = 0.3547
+ XCJC = 1
+ TR = 1.2E-006
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.9552
*
.MODEL Diode D
+ IS = 1.09E-015
+ N = 0.985
+ BV = 1000
+ IBV = 0.001
+ RS = 2382
+ CJO = 0
+ VJ = 1
+ M = 0.5
+ FC = 0
+ TT = 0
+ EG = 1.11
+ XTI = 3
.ENDS
*